--DIRECTOR----------------------------------------------------------------------------------
#DIRECTOR#
    //Must be taken from the Combined Details Section, Check if I have load it on the SLOT 4
    //If WEBSLOT4 has data, the variable 54 must be at 1
    #IF# #54#==#00#
        // no Combined details available        
        #GOTO#=ENDTAKEDIRECTOR
    #ENDIF#
    //OK, slot 4 has data, I load it into memory
    #LOADWEBSLOT5#
    #STARTREADWEB#
    #FINDLINE#=>Directors<#10##ONERROR#=*OK*
    #PUTCURSOR#=#23#
    #IF# #10#==#00#
        // No DIRECTORs found
        #GOTO#=ENDTAKEDIRECTOR
    #ENDIF#
    // Find the end of the DIRECTORs
    // FIND#=<h3 class="ipc-title__text">#22##ONERROR#=*STOP*
    #FIND#=</section>#22#
    #PUTCURSOR#=#22#

    #LOADCURSOR#=#23#

:REPEATDIRECTOR 
    #FIND#="/name/nm#11#
    #IF# #11#==#00#
        #GOTO#=ENDTAKEDIRECTOR
    #ENDIF#
    #IF# #11#>>#22#
        // the search has gone past the directors        
        #GOTO#=ENDTAKEDIRECTOR
    #ENDIF#
    // doesn't take iMDB style of name        
    #FIND#=nm#14##ONERROR#=*OK*
    #FIND#=/#12##ONERROR#=*OK*
    #COMPUTEVAR#=#14#+1
    #TAKEWORD#=#15#,#14#,#12#
    #FIND#=>#14##ONERROR#=*OK*
    #FIND#=<#12##ONERROR#=*OK*
    #TAKEWORD#=#13#,#14#,#12#
    #CHECKVARIABLE#=#13#
    #STARTDELETETAGS#
    #STARTSUBSTITUTETAGS#
    #TRIM#
    #STRING#=#25#=#13#
    #STRING#=#14#=#13#§§#15#
    #STRING#=#13#=#13#§#15#
    #TAKEDIRECTOR#=#13#
    #CHECKACTOREXIST#=#51#,#14#
    #PUTCURSOR#=#08#
    #IF# #51#<>#00#
        // Check if the Actor and his image exist, if exist do not download the picture to speed up import        
        #GOTO#=RETURN2
    #ENDIF#
//GOSUB2
    #PUTCURSOR#=#08#
	#IF# #60#==#00#
     #GOTO#=RETURN2
	#ENDIF#
	#SAVEWEBSITELINE#
	#STRING#=#18#=#31#/name/nm#15#/?ref_=tt_ov_dr
	#STRING#=#15#=#14#
	#PUT#=2#99#
	#GOTO#=ACTORSSUB
:RETURN2 
    #LOADCURSOR#=#08#
    #GOTO#=REPEATDIRECTOR

:ENDTAKEDIRECTOR 
    #RESTOREMAIN#    
	#STARTREADWEB#
	#FINDLINE#="creator":[{#12##ONERROR#=*STOP*
	#PUT#=#16#
	#FIND#=]#20# #ONERROR#=*OK*
	#PUTCURSOR#=#22#
	#STARTREADWEB#
	#FINDLINE#="creator":[{#12##ONERROR#=*STOP*
    #FIND#="name"#20#
	#IF# #20#>>#22#
     #GOTO#=ENDFINALCREATOR
	#ENDIF#
	#FIND#=:"#11#
	#FIND#="#11#
	#FIND#="}#12#
    #TAKEWORD#=#15#,#11#,#12#
    #CHECKVARIABLE#=#15#
    #STARTSUBSTITUTETAGS#
    #STARTDELETETAGS#
    #TRIM#
    #STRING#=#16#=#16##15#
	
:CYCCREATORLINE 
    #FIND#="name"#20##ONERROR#=*OK*
	#IF# #20#>>#22#
        #GOTO#=ENDFINALCREATOR
	#ENDIF#
	#IF# #20#==#00#
        #GOTO#=ENDFINALCREATOR
	#ENDIF#
	#FIND#=:"#11#
	#FIND#="#11#
	#FIND#="}#12#
    #TAKEWORD#=#15#,#11#,#12#
    #CHECKVARIABLE#=#15#
    #STARTSUBSTITUTETAGS#
    #STARTDELETETAGS#
    #TRIM#
    #STRING#=#16#=#16#|#15#
	#GOTO#=CYCCREATORLINE

:ENDFINALCREATOR 
	#TAKECUSTOM3#=#16#
#ENDDIRECTOR#

#CREATEMOVIELIST#
	#PUT#=0#17#
	#STARTREADWEB#
	#FINDLINE#=<ul class="ipc-metadata-list#23##ONERROR#=*OK*
	#IF# #23#==#00#
		#GOTO#=SERIESNOTFOUND
	#ENDIF#
	#STARTREADWEB#
	#FINDLINE#=<div class="sc-4be28cfe-0 elXSkc">#10# #ONERROR#=*STOP*
	#REPEAT#
		#FIND#=div class="sc-4be28cfe-0 elXSkc">#10# #ONERROR#=*STOP*
		#PUTCURSOR#=#10#
		#FIND#=/title/#04#
		#FINDPREVIOUS#=class="ipc-image"#11# #ONERROR#=*OK*
		#IF# #11#<<#10#
			#PUT#=#08#
			#LOADCURSOR#=#10#
			#GOTO#=NOCOVERPICFOUND
		#ENDIF#
		#FIND#=src="#04#
		#FIND#="#04#
		#FIND#=.jpg#05#
		#FIND#="#05#
		#TAKEWORD#=#08#,#04#,#05#  //Coverpic
:NOCOVERPICFOUND 
		#FIND#= href="#04#
		#FIND#="#04#
		#FIND#=/?ref_=#05#
		#TAKEWORD#=#06#,#04#,#05#  //Link
		#FIND#=>#04#
		#FIND#=</a>#05#
		#TAKEWORD#=#07#,#04#,#05#  //Title

:NEXTSPAN 
		#PUTCURSOR#=#10#
		#FIND#=<div class="sc-4be28cfe-0 elXSkc">#11#
		#LOADCURSOR#=#10#

		#FIND#=<span class="#04#
		#IF# #04#>>#11#
			#LOADCURSOR#=#10#
			#GOTO#=CHECKINFO
		#ENDIF#
		#FIND#=>#04#
		#FIND#=</span>#05#
		#TAKEWORD#=#09#,#04#,#05#  //Info
		#STRING#=#07#=#07# (#09#)
		#GOTO#=NEXTSPAN
		
:CHECKINFO 
		#CHECKVARIABLE#=#07#
		#STARTSUBSTITUTETAGS#
		#CLEARTAGS#
		#STARTDELETETAGS#
		#WRITETITLELIST#=https://www.imdb.com/#06#    ---> #07# §#08#
	#WHILE# #00#<>#10#
:ENDMLIST 
	#IF# #17#==#00#
		#GOTO#=SERIESNOTFOUND
	#ENDIF#
	#GOTO#=ENDCREATEMOVIELIST

:SERIESNOTFOUND 
	// No titles were found		    
	#WRITETITLELIST#= ~~~~~~~~   The script couldn't find any titles matching that name.   ~~~~~~~~
	#WRITETITLELIST#= 
	#WRITETITLELIST#= If you know an alternative name for this movie then you could try to enter it
	#WRITETITLELIST#= again and after make import again							
	#WRITETITLELIST#=  
	#WRITETITLELIST#= If it still doesn't find anything then try to go to this page and search for it manually:
	#WRITETITLELIST#= https://www.imdb.com/search   
	#WRITETITLELIST#= 
	#WRITETITLELIST#= If you could find it manually then please post a bugreport in this thread in the XMM forum:
	#WRITETITLELIST#= http://www.binaryworks.it/forum/topic.asp?TOPIC_ID=772 
:ENDCREATEMOVIELIST 
#ENDCREATEMOVIELIST#